lsl second life Kept simple: Rotate object towards another object

[Chalice Yao]

(Re-post from SLU due to popularity)

Here is a little snippet for the rotationally-challenged, or those who have some complex solution but want something much simpler.
How to rotate an object so it points its X axis (which is the 'forward' axis on prims) towards another object?
One complex solution is to take the object's rotation, take the other object's position, try to calculate the angle/rotation in between, adding it to the current rotation...

Way too complex. It's much simpler to calculate the total rotation that needs to be set in one swoop.

Here goes:

llSetRot(llRotBetween(<1,0,0>,llVecNorm(targetPosition - llGetPos())));

Awesome, isn't it? That one line does all the magic. The logic here is that the llRotBetween returns the rotation between the norm'd vector <1,0,0>, which would be the forward vector of an object without any rotation applied (remember, X axis = forward in prims), and the normal vector that points from your object to the target. And that's the whole rotation that needs to be set.

Now, this is already dead seksi, but it can have an effect that some people want to avoid: the object that does the pointing will rotate around its own length. I.e. it will roll left/right along its body axis. How to avoid that?

Solution: Do two different rotations. one that does the left/right turning, followed by a rotation that simply tilts the object up/down. Think of a classic concept like a gun turret. The turret barrel never rotates around the axis it points at, it just moves up/down and left/right.

Hokay, let's do the up/down first. The easiest way to get that rotation is to act like both object positions have the same Y value, and just are their combined XY distance apart on the X axis. Think two-dimensional.

                     B
                     *
                     |   Z height
                     |
A     XYdistance     |
*--------------------------- X axis (<1,0,0>)

So we do:

vector vTarget=target position;
vector vPos=llGetPos(); //object position
float fDistance=llVecDist(<vTarget.x,vTarget.y,0>,<vPos.x,vPos.y,0>); // XY Distance, disregarding height differences.

And then we get back to the little first line of code in this post, modified:

llRotBetween(<1,0,0>,llVecNorm(<fDistance,0,vTarget.z - vPos.z>))

Ta-dah. This will return the rotation that will make our object point upward correctly at the other object. Not left/right, just the correct upwards angle. the 'vTarget.z - vPos.z' gets done to get the height difference between the two objects.

Now how to do left/right? Easy, it uses the same idea as the above concept of getting the needed up/down rotation, except this time we disregard the Z coordinate and just use the XY difference.

Like this:

Y
^
|
|                                 *B
|
|
|    *A
|
------------------> X (<1,0,0>)

This time we don't even need to take care of any distance considerations. What we want, we'll get with:

llRotBetween(<1,0,0>,llVecNorm(<vTarget.x - vPos.x,vTarget.y - vPos.y,0>))

There we go. The needed left/right rotation. Now, let's combine and get the result!

vector vTarget=llList2Vector(llGetObjectDetails("targetkey",[OBJECT_POS]),0);
vector vPos=llGetPos(); //object position
float fDistance=llVecDist(<vTarget.x,vTarget.y,0>,<vPos.x,vPos.y,0>); // XY Distance, disregarding height differences.
llSetRot(llRotBetween(<1,0,0>,llVecNorm(<fDistance,0,vTarget.z - vPos.z>)) * llRotBetween(<1,0,0>,llVecNorm(<vTarget.x - vPos.x,vTarget.y - vPos.y,0>)));

We take the up/down rotation, and multiply the left/right roation to it..which is the way of combining rotations...and it basically goes in reverse order. Think of the left/right applied first before the up/down gets done to the result rotation. Basically read from right to left when mupltiplying rotations.

And there we go. Correct rotation towards a target without rotating around the own axis. Hope this was educational!

Edit #2: up/down * left/right. I swear, that part is too easy to get wrong.

 

[Arlequin]

Hello

Regarde cette instruction, cela fonctionne très bien et je l'utilise dans mes scripts.
Il n'y a pas de retard.
llLookAt

//Causes Object to look at nearest Avatar.
default
{
    state_entry()
    {
        llSensorRepeat("", "", AGENT, 20.0, PI, 0.2);
    }
 
    sensor(integer total_number)
    {
        llLookAt( llDetectedPos(0) + <0.0, 0.0, 1.0>, 3.0, 1.0 );
    }
}

Ou pour un objet:

llSensorRepeat("","", ACTIVE+PASSIVE, 96, PI,0.1);
puis

sensor(integer s){

integer x = 0;
for(;x<s;++x){
llLookAt(llDetectedPos(x),.5,.5);
......



LlLookAt - Second Life Wiki

Voilà, si ça peut aider

 

[Innula Zenovka]

llLookAt works well if you want to point the object's positive z axis at a target. If you need to use another axis, though, it's not so good.

llLookAt fonctionne bien si vous voulez pointer l'axe z positif de l'objet sur une cible. Si vous devez utiliser un autre axe, ce n'est pas si bon que ça.

 

[Adeon Writer]

llLookAt works well if you want to point the object's positive z axis at a target. If you need to use another axis, though, it's not so good.

llLookAt fonctionne bien si vous voulez pointer l'axe z positif de l'objet sur une cible. Si vous devez utiliser un autre axe, ce n'est pas si bon que ça.

Use llLookAt to point it's positive Z at something, then rotate it by 90 degrees on local X or Y to point X or Y at it.

</bigbrain>

 

[Brunswick Warburton]

This multi rotbetween solution is genius. Im using it for the pointat mode of our camera spline system

 

[Free]

This cannot be a spam run. Or can it...

 

[Kokoro Fasching]

This cannot be a spam run. Or can it...

Is it semi soft and salty?

 

[Free]

Is it semi soft and salty?

Is that what spam tastes like? Ewww...

 

[Dorex]

This works great for the X axis but not the Y or Z

// Y axis
llSetRot(llRotBetween(<0,1,0>,llVecNorm(<fDistance,0,vTarget.z - vPos.z>)) * llRotBetween(<0,1,0>,llVecNorm(<vTarget.x - vPos.x, vTarget.y - vPos.y, 0>)));
// Z axis
llSetRot(llRotBetween(<0,0,1>,llVecNorm(<fDistance,0,vTarget.z - vPos.z>)) * llRotBetween(<0,,0,1>,llVecNorm(<vTarget.x - vPos.x, vTarget.y - vPos.y, 0>)));

 

[Soen Eber]

This cannot be a spam run. Or can it...

Probably not. This is one of the deeper mysteries of LSL rotations that scripters are always finding themselves needing to understand. Just because it's so useful and has so many applications.

There, now I've posted in the thread. I'll be able to find this again when I need it.